Tipp 025 Alle Adminrechte nötig

onOffice Tipps und Tricks – 025

In Tipp 024 habe ich die „Guten Tag"-Briefanrede mit zwei Hilfsfeldern gebaut. Das ist übersichtlich, kostet aber zwei zusätzliche Felder. Wer lieber mit nur einem einzigen Formelfeld auskommen will, kann die Namensbausteine auch direkt in die große Formel einbauen – wird zwar deutlich länger, geht aber ohne Hilfsfelder.

Gleichzeitig habe ich noch eine Lücke geschlossen: Tragen beide Personen denselben Nachnamen, kürzt die Formel jetzt auf „Guten Tag Erika und Max Mustermann," ab – statt den Nachnamen zweimal zu nennen. Das erkennt die Formel auch dann, wenn du bei Person 2 den Nachnamen einfach leer lässt, weil er ja ohnehin derselbe ist wie bei Person 1.

IF(
  OR([Vorname2]<>"";[Name2]<>"";[Anrede2]<>"");
  IF(
    AND([Vorname]<>"";[Vorname2]<>"";OR([Name2]="";[Name2]=[Name]));
    "Guten Tag "&IF(AND([Anrede2]="Frau";[Anrede]<>"Frau");[Vorname2]&" und "&[Vorname];[Vorname]&" und "&[Vorname2])&" "&[Name]&",";
    "Guten Tag "&IF(
      AND([Anrede2]="Frau";[Anrede]<>"Frau");
      IF([Vorname2]<>"";IF([Titel2]<>"";[Titel2]&" ";"")&[Vorname2]&" "&IF([Name2]<>"";[Name2];[Name]);IF([Anrede2]<>"";[Anrede2];"Herr/Frau")&" "&IF([Titel2]<>"";[Titel2]&" ";"")&IF([Name2]<>"";[Name2];[Name]))&" und "&IF([Vorname]<>"";IF([Titel]<>"";[Titel]&" ";"")&[Vorname]&" "&[Name];IF([Anrede]<>"";[Anrede];"Herr/Frau")&" "&IF([Titel]<>"";[Titel]&" ";"")&[Name]);
      IF([Vorname]<>"";IF([Titel]<>"";[Titel]&" ";"")&[Vorname]&" "&[Name];IF([Anrede]<>"";[Anrede];"Herr/Frau")&" "&IF([Titel]<>"";[Titel]&" ";"")&[Name])&" und "&IF([Vorname2]<>"";IF([Titel2]<>"";[Titel2]&" ";"")&[Vorname2]&" "&IF([Name2]<>"";[Name2];[Name]);IF([Anrede2]<>"";[Anrede2];"Herr/Frau")&" "&IF([Titel2]<>"";[Titel2]&" ";"")&IF([Name2]<>"";[Name2];[Name]))
    )&","
  );
  IF(
    [Anrede]="Familie";
    "Guten Tag Familie "&[Name]&",";
    IF(
      [Anrede]="Eheleute";
      "Guten Tag Eheleute "&[Name]&",";
      IF(
        [Anrede]="Firma";
        IF([Vorname]<>"";"Guten Tag "&IF([Vorname]<>"";IF([Titel]<>"";[Titel]&" ";"")&[Vorname]&" "&[Name];IF([Anrede]<>"";[Anrede];"Herr/Frau")&" "&IF([Titel]<>"";[Titel]&" ";"")&[Name])&",";"Guten Tag verehrte Damen und Herren,");
        "Guten Tag "&IF([Vorname]<>"";IF([Titel]<>"";[Titel]&" ";"")&[Vorname]&" "&[Name];IF([Anrede]<>"";[Anrede];"Herr/Frau")&" "&IF([Titel]<>"";[Titel]&" ";"")&[Name])&","
      )
    )
  )
)

Wichtig

Wie bei Tipp 024 sind die Zeilenumbrüche hier nur für die Lesbarkeit da – im Formelfeld kannst du sie stehen lassen oder alles in eine Zeile packen. Eine zweite Person wird erkannt, sobald irgendeines der Felder Anrede2, Vorname2 oder Name2 gefüllt ist – nicht nur am Nachnamen, weil der ja gerade bei gleichem Nachnamen oft leer bleibt.

Beispiele:

Erika und Max, beide „Mustermann" (egal ob bei Person 2 explizit „Mustermann" eingetragen oder Name2 leer gelassen): „Guten Tag Erika und Max Mustermann,"
Erika Mustermann und Max Müller (unterschiedliche Nachnamen): „Guten Tag Erika Mustermann und Max Müller," – die Dame steht immer vorne, egal ob sie als Person 1 oder Person 2 gepflegt ist.
Nur Person 1, kein Vorname: „Guten Tag Herr Mustermann,"
Firma ohne Ansprechpartner: „Guten Tag verehrte Damen und Herren,"
Familie/Eheleute: „Guten Tag Familie Mustermann," bzw. „Guten Tag Eheleute Mustermann,"

Aus der Praxis

Zwei Felder oder ein Feld – beide Formeln liefern dasselbe Ergebnis. Zwei Hilfsfelder (Tipp 024) sind übersichtlicher und leichter zu warten, ein einzelnes Feld spart dafür zwei zusätzliche individuelle Felder in deiner Datenbank.