onOffice Tipps und Tricks – 026

Neben der lockeren „Guten Tag"-Variante aus Tipp 024 und Tipp 025 gibt es bei mir noch eine ältere, etwas klassischere Formel mit „Liebe/Lieber" – inklusive einem Kniff, mit dem sich die Automatik pro Datensatz jederzeit von Hand überschreiben lässt.

Die Formel behandelt Anrede und Anrede2 getrennt und hängt die Zeile für Person 2 einfach an die von Person 1 an. Eine Ausnahme gibt es: Ist Person 1 „Herr" und Person 2 „Frau", werden beide Zeilen zusammen im ersten Teil der Formel erzeugt, mit der Dame zuerst – der zweite Teil überspringt Person 2 in diesem Fall extra, damit sie nicht doppelt auftaucht. Bei allen anderen Kombinationen steht einfach Person 1 vor Person 2.

IF([ind_INDIVIDUELLE_BRIEFANREDE]<>"";[ind_INDIVIDUELLE_BRIEFANREDE];IF(AND([Anrede2]="Frau";[Anrede]="Herr");"Liebe Frau "&IF([Titel2]<>"";[Titel2]&" ";"")&[Name2]&",
lieber Herr "&IF([Titel]<>"";[Titel]&" ";"")&[Name]&",";IF([Anrede]="Herr";"Lieber Herr "&IF([Titel]<>"";[Titel]&" ";"")&[Name]&",";IF([Anrede]="Frau";"Liebe Frau "&IF([Titel]<>"";[Titel]&" ";"")&[Name]&",";IF([Anrede]="Familie";"Liebe Familie "&IF([Titel]<>"";[Titel]&" ";"")&[Name]&",";IF([Anrede]="Eheleute";"Liebe Eheleute "&IF([Titel]<>"";[Titel]&" ";"")&[Name]&",";IF([Anrede]="Firma";"Sehr geehrte Damen und Herren,"))))))&IF([Anrede2]="Herr";"
lieber Herr "&IF([Titel2]<>"";[Titel2]&" ";"")&[Name2]&",";IF(AND([Anrede2]="Frau";[Anrede]<>"Herr");"
liebe Frau "&IF([Titel2]<>"";[Titel2]&" ";"")&[Name2]&",";IF([Anrede2]="Familie";"
liebe Familie "&IF([Titel2]<>"";[Titel2]&" ";"")&[Name2]&",";IF([Anrede2]="Eheleute";"
liebe Eheleute "&IF([Titel2]<>"";[Titel2]&" ";"")&[Name2]&",";IF([Anrede2]="Firma";"
Sehr geehrte Damen und Herren,"))))))

(ind_INDIVIDUELLE_BRIEFANREDE ist ein Platzhalter für die Feld-ID meines eigenen Feldes „Individuelle Briefanrede" – bei dir trägt es eine andere ID.)